SI.ERROR en Excel: cómo lidiar con contratiempos

El condicionante SI se usa mucho en Excel para construir fórmulas y determina que una acción solo se ejecute si se da una condición específica. Por norma general, esta condición hace referencia a valores o una secuencia de caracteres concretos. Pero, con mucha mayor frecuencia de la deseada, Excel emite mensajes de error en una celda. El motivo puede ser que hayas escrito mal la fórmula o que le falten valores para un cálculo correcto. En estos casos, puedes crear una alternativa aceptable con la función SI.ERROR.

¿Para qué sirve SI.ERROR en Excel?

Siempre que Excel no sea capaz de ejecutar correctamente un cálculo o una acción, el programa generará un mensaje de error en la celda. Estos mensajes suelen comenzar con una almohadilla (#).

  • #N/A: la fórmula no es capaz de encontrar lo que debe buscar.
  • #¡VALOR!: un argumento cuenta con el tipo erróneo.
  • #¡REF!: la fórmula hace referencia a una celda no válida.
  • #¡DIV/0!: se muestra si intentas realizar una división entre un celda que está vacía o que tiene el valor CERO.
  • #¡NUM!: la fórmula espera un valor numérico pero se encuentra con otra cosa.
  • #¿NOMBRE?: suele emitirse si se ha colado una errata en el nombre de la función.
  • #¡NULO!: aparece si se asignan puntos de intersección que no existen.

En la mayoría de los casos, puedes tratar de resolver el problema subyacente. Pero también puede darse el caso de que ya cuentes de antemano con este tipo de errores y no quieras solucionarlos. En este caso, merece la pena hacer uso de la función SI.ERROR de Excel. Esta función te permite, por ejemplo, sustituir la indicación del error por un mensaje propio o un valor.

Esta medida no solo te ayuda a mantener la hoja de cálculo más ordenada, sino que también impide que los demás cálculos se vean afectados. Si en otra fórmula has especificado un rango de celdas en donde aparece un mensaje de error, es posible que esta fórmula genere un nuevo error. Para evitar esta situación, SI.ERROR te permite introducir un valor con el que la fórmula pueda trabajar.

Hecho

Excel también cuenta con la función ESERROR. Esta emite los valores VERDADERO o FALSO en relación con la aparición de errores. No obstante, la mayoría de usuarios la integran en una función SI. SI.ERROR permite ahorrarse el anidamiento.

Sintaxis de la función SI.ERROR

Con la fórmula SI.ERROR, la hoja de cálculo te lo pone más fácil que nunca. Solo necesitas rellenar dos argumentos: ¿Dónde puede surgir un error? ¿Qué debe pasar si surge un error?

=SI.ERROR(valor; valor_si_error)

¿Qué hay que introducir en los argumentos?

  • Valor: aquí se encuentra el elemento que se debe comprobar en busca de un error. Puedes introducir directamente un cálculo u otra función o hacer referencia a una celda.
  • Valor_si_error: en este punto debes introducir qué debe suceder en caso de error. Puedes introducir valores numéricos, secuencias de caracteres u otras funciones. Si deseas que se indique un texto, debes introducirlo rodeado de comillas dobles.
Nota

En Excel, las fórmulas siempre comienzan por el símbolo igual (=). Si no lo pones, la fórmula aparecerá como texto convencional en la celda. Si es esto lo que quieres e incluso deseas que también se muestre el símbolo de igual en la celda, debes colocar una comilla simple delante de la fórmula (').

Explicación de SI.ERROR con ejemplos

La función de Excel se puede usar en distintas situaciones, por sí sola o en combinación con otras funciones.

Indicación alternativa con SI.ERROR

Probablemente la forma más sencilla de aplicar SI.ERROR al trabajo con Excel sea modificar la notificación del error. En este contexto, imaginemos un cálculo sencillo: el valor de la celda A3 se multiplica por el valor de la celda B3. Si en una de las dos referencias hay una letra en lugar de un número, por ejemplo, debido a una errata, Excel emite el mensaje de error #¡VALOR!. No obstante, si enlazas el cálculo con la función SI.ERROR, puedes cambiar cómo se muestra este fallo.

=SI.ERROR (A3*B3; "valores erróneos")
Consejo

Si deseas que la celda permanezca vacía en caso de error, introduce dos comillas seguidas.

Ahora se indicará el resultado correcto o tu mensaje de error personalizado (en nuestro caso, “valores erróneos”). Si cuentas con varios cálculos de este tipo, puedes aplicar la fórmula a todas las celdas.

En lugar de sustituir el mensaje de error, también puedes aplicar SI.ERROR a otra celda y crear, así, un comentario.

=SI.ERROR (C3; "Aquí hay un error")

En este caso, la función vuelve a indicar el valor de C2 aunque no exista un error. El motivo es que la función SI.ERROR no conoce ningún valor alternativo. Si quieres evitar esta circunstancia, la combinación de SI y ESERROR parece la mejor opción.

=SI(ESERROR(C2)=VERDADERO; "Aquí hay un error"; "")

SI.ERROR y BUSCARV: evitar #N/A

En el uso práctico de Excel, SI.ERROR resulta especialmente útil en combinación con la función BUSCARV. Esta función es conocida por emitir regularmente el error #N/A. La función BUSCARV te ayuda a aplicar una función de búsqueda directamente en tu hoja de Excel. No obstante, si cometes un error en la sintaxis de la fórmula o una errata en el término de búsqueda, Excel emite un mensaje de error. SI.ERROR te permite sustituir el mensaje #N/A, de muy poca utilidad, por un mensaje propio.

=SI.ERROR(BUSCARV("Lung, Fritz";A2:C7;2;0); "Introducción errónea")

La búsqueda del término “Lung, Fritz” provocaría la indicación del error #N/A, ya que el nombre no aparece en la tabla (como el último argumento de BUSCARV está ajustado a 0, no se permiten valores aproximados). Pero, como has anidado la función con SI.ERROR, aparece tu propio mensaje de error en lugar del mensaje estándar.

Si deseas acoplar varias BUSCARV entre sí, la función SI.ERROR también es muy útil. Imaginemos que quieres buscar un objeto en una tabla. Si no se encuentra el objeto, deseas que se compruebe la siguiente tabla y así sucesivamente. Como BUSCARV genera un error si no es posible encontrar el texto introducido, SI.ERROR permite iniciar una nueva BUSCARV.

=SI.ERROR(BUSCARV(100;A3:B7;2;0);SI.ERROR(BUSCARV(100;D3:E7;2;0);SI.ERROR (BUSCARV(100;G3:H7;2;0);"No encontrado")))

Cada vez que BUSCARV no encuentre el argumento buscado y genere un error, la función salta a la siguiente tabla. Si el valor no aparece en ninguna de las tablas y ya se han ejecutado todas las funciones del anidamiento, aparecerá el mensaje que hayas definido.

Hecho

Excel también cuenta con la función SI.ND. Funciona como SI.ERROR, pero su actividad se limita al mensaje de error #N/A. Es decir, si te decantas por esta función en lugar de la función más general, solo filtrarás el error #N/A. Los demás errores se seguirán indicando. De esta forma, podrás reaccionar mejor a los errores en tu fórmula.

SI.ERROR y SUMA: Sustituir errores por un valor

Imaginemos que cuentas con varios cálculos y deseas sumar los resultados con la función SUMA. Si has cometido un error en los cálculos y Excel te indica un mensaje de error en lugar de un valor numérico, es posible que la función para sumar tampoco se ejecute correctamente. Por ello, asegura tus cálculos con SI.ERROR e indica el valor 0 en lugar del error. Así la función puede ejecutar la tarea y la suma no se altera.

=SI.ERROR(A3*B3; 0)

También tienes la opción aplicar un texto alternativo solo a la función SUMA para advertir al usuario del error.

=SI.ERROR(SUMA(C2:C7); "Valores erróneos")
En resumen

Mediante la función SI.ERROR puedes sustituir los mensajes de error de Excel por valores o mensajes propios en distintas situaciones. También puedes usar SI.ERROR para crear fórmulas complejas.

Utilizamos cookies propias y de terceros para mejorar nuestros servicios y mostrarle publicidad relacionada con sus preferencias mediante el análisis de sus hábitos de navegación. Si continua navegando, consideramos que acepta su uso. Puede obtener más información, o bien conocer cómo cambiar la configuración de su navegador en nuestra. Política de Cookies.